Working with the Twitter API was as easy as I remembered it, and getting it to run on a Cron Job on MediaTemple was also very straightforward. The difficulty, for me, was calculating the sunrise and sunset times.

I wanted times that were accurate and went to seconds, so that I could compare the difference of sunlight between days. Using the formulas provided by Moonstick Co. I created the PHP functions which would allow me to get accurate results through interpolation. In regards to these calculations, apart from it being an interesting learning experience, it was a waste of time… PHP 5 date_sunrise :-P

Last year I had the opportunity to speak at ‘Flash on the Beach’. It was a great experience and I would encourage anyone to give it a go for 2010 (26th-29th of April)!

FOTB09 – Elevator Pitch – Trevor Boyle from John Davey on Vimeo.

Here is a short video of our time on the road…

Having experimented with a few options, I settled on the following process:

• Load an external image
• Convert the BitmapData of the image to grey scale
• Perform a histogram equalisation on the BitmapData
• Posterize / limit the BitmapData to the number of colours in the new palette
• Swap the remaining colours in the BitmapData with the colours in the new palette
• Create some effect using the new BitmapData

And here is the code which takes advantage of the BitmapData.histogram, BitmapData.paletteMap & ColorMatrixFilter :

package com.artionscript.assistants
{
	import com.artionscript.palettes.Palette;
	import flash.display.BitmapData;
	import flash.filters.ColorMatrixFilter;
	import flash.geom.Matrix;
	import flash.geom.Point;
	import flash.geom.Rectangle;
	/**
	 * ...
	 * @author Trevor Boyle
	 */
	public class ImageAssistant
	{
		public static function convertBDToGreyScale(sourceBD:BitmapData):BitmapData {
			//BT.709-5 luminance constants

			var tempBD:BitmapData = sourceBD.clone();

			var greyScaleCMF:ColorMatrixFilter = new ColorMatrixFilter();
			greyScaleCMF.matrix = new Array(
			0.2125, 0.7154, 0.0721, 0, 0,
			0.2125, 0.7154, 0.0721, 0, 0,
			0.2125, 0.7154, 0.0721, 0, 0,
			0, 0, 0, 1, 0);

			tempBD.applyFilter(tempBD, new Rectangle(0, 0, tempBD.width, tempBD.height), new Point(0, 0), greyScaleCMF);

			return tempBD;
		}

		public static function equaliseGreyScaleBDHistogram(sourceBD:BitmapData):BitmapData {
			//concept by http://www.generation5.org/content/2004/histogramEqualization.asp

			var tempBD:BitmapData = sourceBD.clone();

			var v:Vector.<vector .<Number>> = tempBD.histogram();

			var adjustmentMultiplier:Number = 255 / (tempBD.width * tempBD.height);
			var tempAdjustedFreq:int;
			var cumulativeFreq:Number = 0;
			var adjustedRedFreqArr:Array = new Array();
			var adjustedGreenFreqArr:Array = new Array();
			var adjustedBlueFreqArr:Array = new Array();
			for (var i:int=0; i < 256; i++) {
				cumulativeFreq += v[0][i];

				tempAdjustedFreq = cumulativeFreq * adjustmentMultiplier;

				adjustedRedFreqArr[i] = tempAdjustedFreq << 16
				adjustedGreenFreqArr[i] = tempAdjustedFreq << 8
				adjustedBlueFreqArr[i] = tempAdjustedFreq
			}

			tempBD.paletteMap(tempBD, new Rectangle(0, 0, tempBD.width, tempBD.height), new Point(0, 0),
adjustedRedFreqArr, adjustedGreenFreqArr, adjustedBlueFreqArr, null);

			return tempBD;
		}
		
		public static function posterizeGreyScaleBD(sourceBD:BitmapData, depth:int):BitmapData {
			//concept by http://www.axiomx.com/posterize.htm

			var tempBD:BitmapData = sourceBD.clone();

			depth = Math.max(0, Math.min(255, depth));

			var colours:Array = [0x004358, 0x1f8a70, 0xbedb39, 0xffe11a, 0xfd7400];

			var numAreas:Number = 256 / depth;
			var numValues:Number = 255 / (depth - 1);

			var tempArea:int;
			var tempAdjustedFreq:int;
			var tempColour:uint;
			var adjustedRedFreqArr:Array = new Array();
			var adjustedGreenFreqArr:Array = new Array();
			var adjustedBlueFreqArr:Array = new Array();
			for (var i:int = 0; i < 256; i++) {
				tempArea =  Math.floor(i / numAreas);
				trace(colours[tempArea]);
				tempAdjustedFreq = Math.floor(numValues * tempArea);

				tempColour = colours[tempArea];

				adjustedRedFreqArr[i] = tempAdjustedFreq << 16
				adjustedGreenFreqArr[i] = tempAdjustedFreq << 8
				adjustedBlueFreqArr[i] = tempAdjustedFreq
			}

			tempBD.paletteMap(tempBD, new Rectangle(0, 0, tempBD.width, tempBD.height), new Point(0, 0),
adjustedRedFreqArr, adjustedGreenFreqArr, adjustedBlueFreqArr, null);

			return tempBD;
		}

		public static function posterizeGreyScaleBDToPalette(sourceBD:BitmapData, colours:Array):BitmapData {
			//concept by http://www.axiomx.com/posterize.htm

			var tempBD:BitmapData = sourceBD.clone();

			var depth:int = colours.length;

			depth = Math.max(0, Math.min(255, depth));

			trace(depth)

			var numAreas:Number = 256 / depth;
			var numValues:Number = 255 / (depth - 1);

			var tempArea:int;
			var tempAdjustedFreq:int;
			var tempColour:uint;
			var adjustedRedFreqArr:Array = new Array();
			var adjustedGreenFreqArr:Array = new Array();
			var adjustedBlueFreqArr:Array = new Array();
			for (var i:int = 0; i < 256; i++) {
				tempArea =  Math.floor(i / numAreas);
				tempAdjustedFreq = Math.floor(numValues * tempArea);
				tempColour = colours[tempArea];

				adjustedRedFreqArr[i] = ((tempColour >> 16) & 0xFF) < < 16;
				adjustedGreenFreqArr[i] = ((tempColour >> 8) & 0xFF) < < 8;
				adjustedBlueFreqArr[i] = (tempColour & 0xFF);
			}

			tempBD.paletteMap(tempBD, new Rectangle(0, 0, tempBD.width, tempBD.height), new Point(0, 0),
adjustedRedFreqArr, adjustedGreenFreqArr, adjustedBlueFreqArr, null);

			return tempBD;
		}

		public static function scaleBD(sourceBD:BitmapData, width:Number, height:Number, constrain:Boolean=true,
constrainToLargest:Boolean=false):BitmapData {

			var tempBD:BitmapData = sourceBD.clone();

			var scaleX:Number = width / tempBD.width;
			var scaleY:Number = height / tempBD.height;

			if (constrain) {
				if (constrainToLargest) {
					scaleX = scaleY = Math.max(scaleX, scaleY);
				}else{
					scaleX = scaleY = Math.min(scaleX, scaleY);
				}
			}
			var scaleMatrix:Matrix = new Matrix();
			scaleMatrix.scale(scaleX, scaleY);

			var scaledBD:BitmapData = new BitmapData(tempBD.width * scaleX, tempBD.height * scaleY, false, 0x000000);
			scaledBD.draw(tempBD, scaleMatrix);

			return scaledBD;
		}
	}
}

This year was also more special, than the previous years that I have attended, because I was fortunate enough to be able to speak on the main stage for 3 minutes as part of the ‘Elevator Pitch’ session, along with 20 other people.

I also promised during my speech to release the source code for my ’3D Pixelated Video’ project. So, here it is in all its uncommented, unoptimised glory. I have also included a glitchy perlin noise version, which I put together over the past hour, to get you thinking of what you could do with it. Other suggestions include converting it to Papervison and creating some installation art.

3D Isometric Pixelated Video Source Code

It’s basically an image and video blog about all sorts of yucky food.

A new post is added daily.

The idea sprang from a 16 month old sandwich that had been hidden under a desk where I was working.

Please rate, comment, dig, blog, share, contribute and suggest :-)

http://notwhileiameating.com/

The new ActionScript 3.0 Client Library for Facebook Platform API, fully supported by Facebook and Adobe, makes it easy to build applications that combine the strengths of the Flash Platform and Facebook Platform.

I had a few problems trying to find some sample AS3 code, using the new ‘ActionScript 3.0 Client Library for Facebook Platform API‘ which is supported both by Adobeand by Facebook, which wasn’t focused on Flex. So I took Adobe’s ‘BROWSE THUMBNAILS OF FACEBOOK PHOTOS‘ example and converted it into something you can use for Flash.

1. Watch this video http://www.adobe.com/devnet/facebook/articles/video_facebook_quick_start.html
2. Download the ActionScript 3.0 Client Library for Facebook vX.X – Source from http://code.google.com/p/facebook-actionscript-api/downloads/list
3. Setup your facebook application as per the video instructions, making sure you select ‘Desktop’ as your ‘Application Type’ in the advanced tab
4. Create a new Flash AS3 file
5. Open the components panel (Window>Components) and drag to your library the ‘Button’, ‘List’, ‘TileList’ and ‘UILoader’ components
6. Create a new ‘Document class’, named FacebookImageBrowser.as, and assign it to your newly created Flash file
7. Add the following code to your document class and include your own ‘API_KEY’ and ‘SECRET_KEY’, which is listed on your Facebook application’s settings page
8. Publish your movie and step through the buttons as you get feedback

package {
	import flash.display.Sprite;
	import flash.text.TextField;
	import fl.controls.Button;

	import flash.events.Event;
	import flash.events.MouseEvent;
	import fl.events.ListEvent;

	import fl.controls.List;
	import fl.controls.TileList;
	import fl.controls.ScrollBarDirection;

	import fl.data.DataProvider;

	import fl.containers.UILoader;

	import com.facebook.data.photos.AlbumData;
	import com.facebook.data.photos.PhotoData;

	import com.facebook.Facebook;
	import com.facebook.events.FacebookEvent;
	import com.facebook.net.FacebookCall;
	import com.facebook.data.photos.GetAlbumsData;
	import com.facebook.data.photos.GetPhotosData;
	import com.facebook.commands.photos.GetAlbums;
	import com.facebook.commands.photos.GetPhotos;
	import com.facebook.utils.FacebookSessionUtil;

	/**
	* ...
	* @Flex Developer: Steven Shongrunden
	* @Flash Conversion: Trevor Boyle
	*/

	public class FacebookImageBrowser extends Sprite {

		private var fbook:Facebook;
		private var session:FacebookSessionUtil;

		private var API_KEY:String = "XXXXX";
		private var SECRET_KEY:String = "XXXXX";

		private var facebookPhotoAlbums:DataProvider; 

		private var facebookPhotos:DataProvider;

		private var button1:Button
		private var button2:Button
		private var button3:Button

		private var status:TextField;

		private var albumsDataGrid:List;
		private var photosList:TileList;

		private var myUILoader:UILoader;

		function FacebookImageBrowser(){
			trace("FacebookImageBrowser Constructor")
			init()
		}

		private function init():void {
			trace("FacebookImageBrowser.init()")
			session=new FacebookSessionUtil(API_KEY, SECRET_KEY, loaderInfo);
			session.addEventListener(FacebookEvent.CONNECT, onConnect);
			fbook=session.facebook;

			button1 = new Button();
			button1.label = "1. Login to Facebook";
			button1.width = 120;
			button1.move(10, 10);
			button1.addEventListener(MouseEvent.CLICK, session.login)
			addChild(button1);

			button2 = new Button();
			button2.label = "2. Done logging in";
			button2.width = 120;
			button2.move(10, 40);
			button2.addEventListener(MouseEvent.CLICK, doneLoggingIn)
			addChild(button2);

			button3 = new Button();
			button3.label = "3. Browse Photos";
			button3.width = 120;
			button3.move(10, 70);
			button3.addEventListener(MouseEvent.CLICK, getPhotoAlbums)
			addChild(button3);

			status = new TextField();
			status.x = 10;
			status.y = 100;
			status.text = "Please log in"
			status.autoSize = "left"
			addChild(status)

			facebookPhotoAlbums = new DataProvider();

			albumsDataGrid = new List();
			albumsDataGrid.setSize(200,300);
			albumsDataGrid.dataProvider = facebookPhotoAlbums;
			albumsDataGrid.addEventListener(Event.CHANGE, showSelectedAlbum);
			albumsDataGrid.move(10,130)
			addChild(albumsDataGrid);

			facebookPhotos = new DataProvider();

			photosList = new TileList();
			photosList.direction = ScrollBarDirection.VERTICAL;
			photosList.dataProvider = facebookPhotos;
			photosList.sourceFunction = getPhotoDataSourceSmall
			photosList.addEventListener(Event.CHANGE, showSelectedPhoto);
			photosList.columnWidth = 75;
			photosList.rowHeight = 75;
			photosList.columnCount = 4;
			photosList.rowCount = 4;
			photosList.setSize(320,300);
			photosList.move(230,130)
			addChild(photosList);

			myUILoader = new UILoader();
			myUILoader.autoLoad = false;
			myUILoader.scaleContent = false;
			myUILoader.move(10, 440);
			addChild(myUILoader);
		}

		private function onConnect(e:FacebookEvent):void {
			trace("FacebookImageBrowser.onConnect()")
			status.text = "Facebook API Ready";
		}

		private function doneLoggingIn(e:MouseEvent=null):void {
			trace("FacebookImageBrowser.doneLoggingIn()")
			session.validateLogin();
		}

		private function getPhotoAlbums(e:MouseEvent=null):void {
			trace("FacebookImageBrowser.getPhotoAlbums()")
			var call:FacebookCall = fbook.post(new GetAlbums(fbook.uid));
			call.addEventListener(FacebookEvent.COMPLETE, handleGetAlbumsResponse);
		}

		private function handleGetAlbumsResponse(e:FacebookEvent):void {
			trace("FacebookImageBrowser.handleGetAlbumsResponse()")
			var albumsResponseData:GetAlbumsData = e.data as GetAlbumsData;

			if (!albumsResponseData || e.error){ // an error occurred
				status.text = "Error";
				return;
			}

			facebookPhotoAlbums.removeAll()

			var albumData:AlbumData;
			for(var i:int = 0; i < albumsResponseData.albumCollection.length; i++){
				albumData = albumsResponseData.albumCollection.getItemAt(i) as AlbumData
				facebookPhotoAlbums.addItem({label:albumData.name, aid:albumData.aid, cover_pid:albumData.cover_pid,
owner:albumData.owner, name:albumData.name, created:albumData.created, modified:albumData.modified,
description:albumData.description, location:albumData.location, link:albumData.link, size:albumData.size, visible:albumData.visible});
			}
		}

		private function handleGetPhotosResponse(e:FacebookEvent):void {
			trace("FacebookImageBrowser.handleGetPhotosResponse()")
			var photosResponseData:GetPhotosData = e.data as GetPhotosData;

			if (!photosResponseData || e.error){ // an error occurred
				status.text = "Error";
				return;
			}

			facebookPhotos.removeAll()

			var photoData:PhotoData;
			for(var i:int = 0; i < photosResponseData.photoCollection.length; i++){
				photoData = photosResponseData.photoCollection.getItemAt(i) as PhotoData
				facebookPhotos.addItem({label:photoData.caption, pid:photoData.pid, aid:photoData.aid,
owner:photoData.owner, src:photoData.src, src_big:photoData.src_big, src_small:photoData.src_small, link:photoData.link,
caption:photoData.caption, created:photoData.created});
			}
		}

		private function showSelectedAlbum(e:Event):void {
			trace("FacebookImageBrowser.showSelectedAlbum()")
			facebookPhotos.removeAll()

			var selectedAlbumID:String = albumsDataGrid.selectedItem.aid;

			var call:FacebookCall = fbook.post(new GetPhotos('', selectedAlbumID));
			call.addEventListener(FacebookEvent.COMPLETE, handleGetPhotosResponse);
		}

		private function showSelectedPhoto(e:Event):void {
			trace("FacebookImageBrowser.showSelectedPhoto()")
			var selectedPhoto:String = getPhotoDataSourceBig((photosList.selectedItem as Object));

			myUILoader.source = selectedPhoto
			myUILoader.load();
		}

		private function getPhotoDataSource(item:Object):String {
			return item.src;
		}

		private function getPhotoDataSourceSmall(item:Object):String {
			return item.src_small;
		}

		private function getPhotoDataSourceBig(item:Object):String {
			return item.src_big;
		}
	}
}

Having had a few days off from work over the Easter break, I decided to… work.

Using the AS3 twitterscript library (http://code.google.com/p/twitterscript/) and a php proxy script by Woven Interactive (http://woveninteractive.net/?p=45) I have created a simple flash visualisation of Twitter’s Twittersphere.

The flash application periodically requests the latest tweets from Twitter and then animates them in the sky.

I plan to add some search functionality to it at a later date, but it’s now time to go buy some cheap Easter eggs and drink some beer.

Twittersphere Visualizer

1. Download an svn client, such as TortoiseSVN (http://tortoisesvn.net/downloads)
2. Using your client, download the latest .as (AS3) files from http://twitterscript.googlecode.com/svn/trunk
3. Create a new Flash AS3 file
4. Create a new ‘Document class’, named TwitterUserFeed.as, and assign it to your newly created Flash file
5. Add the following code to your document class (updating your package name and TWITTER_USER accordingly)
6. Publish the movie and watch the ‘output’ panel
7. View the Twitter.as file to help you extend this example

package com.trevorboyle.twitter
{
	import flash.display.Sprite;
	import twitter.api.data.TwitterStatus;
	import twitter.api.Twitter;
	import twitter.api.TwitterSearch;
	import twitter.api.events.TwitterEvent;

	/**
	 * ...
	 * @author Trevor Boyle
	 */
	public class TwitterUserFeed extends Sprite
	{
		private static const TWITTER_USER:String = "stephenfry";

		private var _twitter:Twitter;
		private var _twitterSearch:TwitterSearch;

		public function TwitterUserFeed()
		{
			_twitter = new Twitter();
			_twitterSearch = new TwitterSearch();

			_twitter.loadUserTimeline(TWITTER_USER)
			_twitter.addEventListener(TwitterEvent.ON_USER_TIMELINE_RESULT, userTimelineResult)
		}

		private function userTimelineResult(e:TwitterEvent):void {
			var twitterStatus:TwitterStatus;
			for (var i in e.data) {
				twitterStatus = e.data[i]
				trace(twitterStatus.text)
			}
		}
	}
}